;===============================================================================================================================
;                    DCC Clones Detector version 1.0 by BiskutMeri
; Discription
; Avoid 2 or more clone (nickname from same IP) from taken all your available DCC slot. This script will check every <second> that   
; you set and locate active dcc which have same IP address and Dissmiss all the session. The notice will be send to the clones. 
; so they need to request again the files. and the cycle begin if they still used clone for your dcc. 
;
; WARNING : By using this script, Im not taking any responsible for anything happen to your PC/Machine. Using this script 
;           is under your own responsiblity. 
; 
; System REquirement: mirc version 6.03++ (Tested on Mirc v6.16, P4 1.8Mhz , 512Mb, Windows XP) 
; 
; ==================================( Created For Jiwang Fserv Team by BiskutMeri )============================================== 

menu * { 
  - 
  DCC CLONE DETECTOR
  .$iif(!$dialog(dccclone),Configuration):dialog -m dccclone dccclone
  .-
  .Documentation:.run notepad readme.txt 
  -
} 
on *:load:{ 
  echo -s $timestamp Loaded Mascovy Fserv Detector version 2.0 
  echo -s $timestamp Design by BiskutMeri/Mascovy © 2006 
  set %ann FServ Online: &Fservnick
  writeini fservdetect.ini Malaynet #jiwang 300 
} 
on *:unload:{ 
  if ($timer(dccip)) .timerdccip off
  unset %dccclone* 
  echo *** Successful unloaded $script
} 
dialog dccclone {
  title "DCC Clones Detector. [ Abort Send Files For Clones ]"
  size -1 -1 156 61
  option dbu
  box "Setting && Configuration", 1, 1 3 154 57
  check "Enable Checker every", 2, 8 11 65 10
  button "+", 3, 73 12 11 10
  button "-", 4, 106 12 11 10
  edit "", 5, 85 12 20 10, read center
  text "Termination Message", 6, 7 24 53 8
  edit "Hey Dude!!! Please dont used clones For my DCC server", 7, 7 33 143 10, autohs
  text "second", 8, 120 14 25 8
  button "&Dismiss", 9, 111 46 37 10, ok
  link "About", 11, 6 48 22 8
}
dialog myself {
  title "About Mascovy DCC Clone detector"
  size -1 -1 114 49
  option dbu
  box "", 1, 1 1 112 47
  text "Mascovy DCC CLONE Detector v1.0 Copyright © 2006", 2, 31 9 75 15
  link "Design By Mascovy", 3, 32 26 71 8
  link "https://mascovy.tripod.com/", 4, 32 35 70 8
  icon 5, 7 17 20 18, $mircexe , 18
}
alias -l my.info if (!$dialog(aboutme)) dialog -ma myself myself
on 1:dialog:myself:sclick:*:if ($did == 3) .run mailto:mindforce83@yahoo.com | if ($did == 4) .run https://mascovy.tripod.com/
on 1:dialog:dccclone:*:*:{
  if ($devent == init) { 
    if (%dccclone.set) did -c $dname 2 
    did -ra $dname 5 $dccclone(delay) 
    did -ra $dname 7 $dccclone(msg) 
  }
  if ($devent == sclick) { 
    if (($did == 4) && ($did(5) > 0)) { did -ra $dname 5 $calc($did(5) - 1) } 
    if (($did == 3) && ($did(5) < 1500)) { did -ra $dname 5 $calc($did(5) + 1) } 
    if ($did == 9) { 
      if ($did(2).state == 1) set %dccclone.set on 
      if ($did(2).state == 0) unset %dccclone.set
      if ($did(7).text != $null) set %dccclone.msg $did(7).text 
      if ($did(5).text != $null) set %dccclone.timer $did(5).text 
      if (%dccclone.set) .timerdccip 0 $dccclone(delay) /dccip 
      if ((!%dccclone.set) && ($timer(dccip))) .timerdccip off 
    }
    if ($did == 11) my.info
  }

}
alias dccclone { 
  if ($1 == delay) return $iif(%dccclone.timer isnum,%dccclone.timer,5) 
  if ($1 == msg) { 
    var %v = I found you just using clone with my dcc server (IP: &ip ). Sorry Im not tolerate with this. All progress DCC terminated. Please only used single DCC from me.
    return $iif(%dccclone.msg,%dccclone.msg,%v) 
  }
}

alias dccip { 
  var %i = 0 
  if (!%dccclone.set) return
  if (!$timer(dccip)) .timerdccip 0 $dccclone(delay) /dccip 
  unset %ipd.* 
  while (%i < $send(0)) { 
    inc %i 
    var %id = $send(%i).ip , %in = $send(%i) , %ip = $send(%i).sent , %lip = $longip(%id) 
    if (%lip isnum) %ipd. [ $+ [ %lip ] ] = $addtok(%ipd. [ $+ [ %lip ] ] ,%in,44) 
    if (%lip isnum) start.chk %id
  }
  var %t = 0
  ;echo -s IM reading this lines alias
  while ($var(%ipd.*,0) > %t) { 
    inc %t 
    var %g = $var(%ipd.*,%t).value , %ep = $gettok($var(%ipd.*,%t),2,46)  
    if ($numtok(%g,44) >= 2) banned-dcc %ep %g 
  } 
} 
alias banned-dcc { 
  var %h = 0 , %ip = $longip($1) , %k = $2- 
  tokenize 44 $2- 
  close -s $1- 
  echo -s DCC clone Detected on %ip Nick: $1- 
  if (%k) .notice %k $replace($dccclone(msg),&ip,%ip,&nick,%k)
}